rem # https://docs.microsoft.com/zh-tw/windows-hardware/manufacture/desktop/configure-uefigpt-based-hard-drive-partitions
rem # https://learn.microsoft.com/zh-tw/windows-hardware/manufacture/desktop/configure-biosmbr-based-hard-drive-partitions?view=windows-11
rem == 2025-03-15 15:24:18

rem == CreatePartitions-BIOS.txt ==
rem ##	 DiskPart /s B:\CreatePartitions-BIOS_AnyDiskSize.txt 	##

rem == 0. Clean Disk ==
rem #edit# select disk N0123
rem #edit# clean

rem == 1. System partition ==
create partition primary size=2048
format quick fs=fat32 label="System" OverRide
assign letter="S" NoErr

rem == 2. Windows partition ==
create partition primary
rem ---- shrink 33 GB ----
shrink desired=33793
format quick fs=ntfs label="Windows" OverRide
assign letter="W" NoErr
active

rem == 3. Recovery partition ==
create partition primary size=1024
format quick fs=ntfs label="Recovery" OverRide
set id=27 OverRide
assign letter="R" NoErr

rem == 4. Restore partition ==
rem ---- extended logical ----
create partition extended size=32769
create partition logical size=32768
format quick fs=ntfs label="Restore" OverRide
assign letter="T" NoErr

list volume
list partition
exit